* Version SOEP 37, Mathis Schroeder, Jan Goebel, Stefan Zimmermann, Selin Kara
* produces figure "Cross-Sectional Development of Sample Size"

global data "\\hume\rdc-gen\consolidated\soep-core\soep.v38\consolidated14\" //  SOEP_v37

clear all
use *netto psample letztbef using ${data}ppfad.dta

qui sum letztbef
local last=r(max)
dis `last'
qui tab psample
local cols=r(r)
levelsof psample, local(samps)
dis "`samps'"
dis "`cols'"

matrix define countme=J(`last'-1984+1,`cols'+1,.)
local row=1
qui foreach wv in a b c d e f g h i j k l m n o p q r s t u v w x y z ba bb bc bd be bf bg bh bi bj bk bl {
   forvalues i=1/`cols' {
       local smp : word `i' of `samps'
       count if inrange(`wv'netto,10,19) & psample==`smp'
       if r(N)>0 {
           matrix countme[`row',`i']=r(N)   
       }	 
   }
   local row=`row'+1
}

local rownm " "
local row=1
forvalues yr=1984/`last' {
   matrix countme[`row',`cols'+1]=`yr'   
   local rownm="`rownm'" + " " + string(`yr')
   local row=`row'+1
}
matrix rownames countme=`rownm'

local colnm "A B C D E F G H I J K L1 L2 L3 M1 M2 M3 M4 M5 N O P Q M6 M7 M8 "
matrix colnames countme=`colnm' year

svmat countme, names(col)
keep A-M8 year
missings dropobs _all, force // dropmiss früher??? / Paket 

* note: set scheme(s2color) to scheme(s2mono) for black and white if necessary. 

#d;
graph bar (first) A B C D E F G H I J K L1 L2 L3 M1 M2 M3 M4 M5 N O P Q M6 M7 M8, over(year, label(angle(ninety))) stack 
   bar( 1, color(red) lcolor(black) lpattern(solid)) bar( 2, color(emidblue) lcolor(black) lpattern(solid)) bar( 3, color(brown) lcolor(black) lpattern(solid)) 
   bar( 4, color(cranberry) lcolor(black) lpattern(solid)) bar( 5, color(lavender) lcolor(black) lpattern(solid)) bar( 6, color(green) lcolor(black) lpattern(solid)) 
   bar( 7, color(navy) lcolor(black) lpattern(solid)) bar( 8, color(orange) lcolor(black) lpattern(solid)) bar( 9, color(khaki) lcolor(black) lpattern(solid)) 
   bar(10, color(gray) lcolor(black) lpattern(solid)) bar(11, color(olive) lcolor(black) lpattern(solid)) bar(12, color(blue) lcolor(black) lpattern(solid))
   bar(13, color(purple) lcolor(black) lpattern(solid)) bar(14, color(eltgreen) lcolor(black) lpattern(solid)) bar(15, color(erose) lcolor(black) lpattern(solid))
   bar(16, color(sienna) lcolor(black) lpattern(solid)) bar(17, color(sandb) lcolor(black) lpattern(solid)) bar(18, color(olive_teal) lcolor(black) lpattern(solid))
   bar(19, color(eggshell) lcolor(black) lpattern(solid)) bar(20, color(pink) lcolor(black) lpattern(solid)) bar(21, color(midblue) lcolor(black) lpattern(solid))
   bar(22, color(magenta) lcolor(black) lpattern(solid)) bar(23, color(cyan) lcolor(black) lpattern(solid)) bar(24, color(lime) lcolor(black) lpattern(solid))
   bar(25, color(yellow) lcolor(black) lpattern(solid)) bar(26, color(emerald) lcolor(black) lpattern(solid))
	ylabel(, angle(zero)) 
	legend(order(1 "Sample A" 2 "Sample B" 3 "Sample C" 4 "Sample D1/D2" 5 "Sample E" 
	             6 "Sample F" 7 "Sample G" 8 "Sample H" 9 "Sample I" 10 "Sample J"
                 11 "Sample K" 12 "Sample L1" 13 "Sample L2" 14 "Sample L3" 15 "Sample M1"
                 16 "Sample M2" 17 "Sample M3" 18 "Sample M4" 19 "Sample M5" 20 "Sample N" 
				 21 "Sample O" 22 "Sample P" 23 "Sample Q" 24 "Sample M6"
			     25 "Sample M7" 26 "Sample M8") 
        cols(7) region(lcolor(white)) position(12) symxsize(vsmall) size(vsmall)) 
        scheme(s2color) xsize(20) ysize(13) graphregion(fcolor(white));
#d cr	

graph export "H:/clone/soepcompanion/docs/source/Target Population and Samples/png/crossdevel.png",  replace